;:poke56,32:clr
;:sys36864
	*= $c000
	;.opt oo
mx	=$2
mh	=$3
my	=$4
av	=181
last	=5
	jsr init
wert	lda $dc00
	pha
	and #16
	bne rela
	jsr draw
rela	pla
	and #15
	pha
	and #1
	beq novert
	lda last
	and #1
	bne novert
	pla
	pha
	and #4
	bne oben
	lda my
	cmp #199
	bcs novert
	inc my
	jmp novert
oben	lda my
	beq novert
	dec my
novert	pla
	pha
	and #2
	beq nohori
	lda last
	and #2
	bne nohori
	pla
	pha
	and #8
	bne left
	lda mx+1
	beq oke
	lda mx
	cmp #<319
	bcs nohori
oke	inc mx
	bne nohori
	inc mx+1
	jmp nohori
left	lda mx
	bne uuu
	lda mx+1
	beq nohori
	dec mx+1
uuu	dec mx
nohori	pla
	sta last
	lda mx
	clc
	adc #24
	sta 53248
	lda mx+1
	adc #0
	sta 53264
	lda my
	adc #50
	sta 53249
	lda 56321
	and #16
	bne run
	jsr init
run	jmp wert
init	jsr 65409
	lda #15
	sta 53280
	ldx #63
	lda #0
cs	sta 704,x
	dex
	bpl cs
	tax
	tay
	sty mh
	stx 53248+39
cp	lda pfeil,x
	sta 704,y
	iny
	iny
	iny
	inx
	cpx #8
	bcc cp
	lda #1
	sta 53269
	lda #160
	sta mx
	lda #100
	sta my
	ldx #32
	stx av+1
	ldy #0
	tya
	sta av
cg	sta (av),y
	iny
	bne cg
	inc av+1
	dex
	bne cg
	ldx #4
	stx av+1
	ldy #0
	sty av
	lda #1
ch	sta (av),y
	iny
	bne ch
	inc av+1
	dex
	bne ch
	lda #59
	sta 53265
	lda #29
	sta 53272
	ldx #11
	stx 2040
	rts
pfeil	=*
	.byt %11111100
	.byt %11111000
	.byt %11110000
	.byt %11111000
	.byt %11011100
	.byt %10001110
	.byt %00000111
	.byt %00000011
mult	=*
	.word $2000,$2140,$2280,$23c0
	.word $2500,$2640,$2780,$28c0
	.word $2a00,$2b40,$2c80,$2dc0
	.word $2f00,$3040,$3180,$32c0
	.word $3400,$3540,$3680,$37c0
	.word $3900,$3a40,$3b80,$3cc0
	.word $3e00
gb	.byt 128,64,32,16,8,4,2,1
draw	lda my
	lsr
	lsr
	lsr
	asl
	tay
	lda mult+1,y
	sta av+1
	lda my
	and #7
	clc
	adc mult,y
	sta av
	lda mx
	and #$f8
	adc av
	sta av
	lda av+1
	adc mx+1
	sta av+1
	lda mx
	and #7
	tax
	lda gb,x
	ldy #0
	ora (av),y
	sta (av),y
	rts