;:sys36864
	;.opt oo
vic	=$d000
xk	=vic
yk	=vic+1
se	=vic+21
mx	=vic+16
vicinit	=65409
irqvec	=$314
oldirq	=$ea31
point	=2040
frame	=vic+32
screen	=vic+33
fx	=vic+2
fy	=vic+3
ff	=vic+40
mc	=vic+28
ey	=vic+23
point2	=2041
getkey	=65508
irqspeed	=$dc05
mc1	=vic+37
mc2	=vic+38
	*= 51200
	jsr vicinit
	sei
	lda #<neuirq
	ldy #>neuirq
	sta irqvec
	sty irqvec+1
	lda #1
	sta count
	sta dir
	sta ff
	sta bein
	sta yzaehl
	lda #3
	sta se
	cli
	jmp mann
dir	.byt 1
richt	.byt 1
count	.byt 1
mandir	.byt 0
bein	.byt 1
manfast	.byt 1
manbein	.byt 1
tmp	.byt 0
yzaehl	.byt 1
manrum	.byt 100
neuirq	jsr lauf
	jsr beweg
	jsr updown
	jsr manlauf
	jmp oldirq
lauf	dec count
	bne back
	lda #9
	sta count
	lda dir
	beq beine
	lda #246
	.byt $2c
beine	lda #251
	clc
	adc bein
	sta point
	ldx bein
	inx
	cpx #5
	bcc beineok
	ldx #0
beineok	stx bein
back	rts
beweg	lda dir
	beq stepleft
	ldx xk
	inx
	beq over
	lda mx
	and #1
	beq set
	cpx #75
	bcc set
	lda #0
	sta dir
set	stx xk
	rts
over	lda mx
	ora #1
	sta mx
	jmp set
stepleft	ldx xk
	dex
	cpx #255
	bne set
	lda mx
	and #1
	beq turn
	lda mx
	and #254
	sta mx
	jmp set
turn	lda #1
	sta dir
	inx
	jmp set
updown	dec yzaehl
	bne back
	lda #2
	sta yzaehl
	lda richt
	beq runter
	ldx yk
	dex
	cpx #40
	beq wechs
put	stx yk
	rts
wechs	lda #0
	sta richt
	jmp put
runter	ldx yk
	inx
	cpx #229
	bne put
	stx richt
	jmp put
manlauf	dec manfast
	bne weg
	lda #10
	sta manfast
	lda mandir
	beq man2
	lda #144
	.byt $2c
man2	lda #148
	clc
	adc manbein
	sta point2
	ldx manbein
	inx
	cpx #4
	bcc man1
	ldx #0
man1	stx manbein
weg	rts
mann	lda #0
	sta frame
	sta screen
	lda #255
	sta fx
	sta fy
	lda #2
	sta mc
	sta ey
	lda #5
	sta mc1
	lda #2
	sta mc2
main	jsr key
	ldx #255
	ldy manrum
wait	dex
	bne wait
	dey
	bne wait
	lda fy
	cmp yk
	bcc manoben
	dec fy
	bne manunt
manoben	inc fy
manunt	lda mx
	and #1
	asl
	sta tmp
	lda mx
	and #2
	cmp tmp
	bcc manlink
	bne manrech
	lda xk
	cmp fx
	bcs manlink
manrech	ldx fx
	dex
	cpx #255
	bne m1
	lda mx
	and #253
	sta mx
m1	stx fx
	lda #0
setdir	sta mandir
	jmp main
manlink	inc fx
	bne setman
	lda mx
	ora #2
	sta mx
setman	lda #1
	bne setdir
key	jsr getkey
	beq nokey
	cmp #"\x85"
	beq ende
	cmp #"\x86"
	beq pf1
	cmp #"\x8a"
	beq ma1
	cmp #"\x87"
	beq pf2
	cmp #"\x8b"
	beq ma2
nokey	rts
ende	pla
	pla
	rts
pf1	ldx irqspeed
	inx
	beq nokey
setirq	stx irqspeed
	rts
pf2	ldx irqspeed
	dex
	cpx #255
	bne setirq
	beq nokey
ma1	ldx manrum
	inx
	beq nokey
herr	stx manrum
	rts
ma2	ldx manrum
	dex
	cpx #255
	bne herr
	beq nokey