;:open2,8,2,"install,p,w
;:sys36864
	;.opt o2
	*=$c000
	lda #<crunch
	ldy #>crunch
	sta 772
	sty 773
	lda #<list
	ldy #>list
	sta 774
	sty 775
	lda #<error
	ldy #>error
	sta 768
	sty 769
	jsr $aad7
	lda #<name
	ldy #>name
	jsr $ab1e
	lda #<hi
	ldy #>hi
	jmp $ab1e
hi	.byte " installiert"
	.byt 13,13
	.byte "basic construction set"
	.byt 13,13
	.byte "nikolaus heusler  3.92"
	.byt 13,0
;
token	=$c2ff
fehler	=$c280
name	=$c240
ok	=$c200
;
crunch	ldx $7a
	ldy #4
	sty 15
l2	lda 512,x
	bpl l3
	cmp #-1
	beq l1
	inx
	bne l2
l3	cmp #32
	beq l1
	sta 8
	cmp #34
	beq l4
	bit 15
	bvs l1
	cmp #"?"
	bne l5
	lda #153
	bne l1
l5	cmp #"0"
	bcc l6
	cmp #"<"
	bcc l1
l6	sty $71
	ldy #0
	sty 11
	dey
	stx $7a
	dex
l7	iny
	inx
le	lda 512,x
	sec
	sbc token+1,y
	beq l7
	cmp #$80
	bne l8
	ora 11
lf	ldy $71
l1	inx
	iny
	sta 507,y
	cmp #0
	beq l9
	sec
	sbc #":"
	beq la
	cmp #73
	bne lb
la	sta 15
lb	sec
	sbc #85
	bne l2
	sta 8
lc	lda 512,x
	beq l1
	cmp 8
	beq l1
l4	iny
	sta 507,y
	inx
	bne lc
l8	ldx $7a
	inc 11
ld	iny
	lda token,y
	bpl ld
	lda token+1,y
	bne le
	lda 512,x
	bpl lf
l9	sta 509,y
	dec $7b
	lda #-1
	sta $7a
	rts
;
lg	jmp $a6ef
lh	jmp $a6f3
;
list	bpl lh
	cmp #-1
	beq lh
	bit 15
	bmi lh
	sec
	sbc #$7f
	tax
	sty $49
	ldy #-1
lk	dex
	beq li
lj	iny
	lda token+1,y
	bpl lj
	bmi lk
li	iny
	lda token+1,y
	bmi lg
	jsr $ab47
	bcc li
;
error	txa
	bmi j1
	txa
	asl
	tax
	lda fehler-2,x
	sta $22
	lda fehler-1,x
	sta $23
	jsr $ffcc
	lda #0
	sta $13
	jsr $aad7
	jsr $ab45
	ldy #0
j2	lda ($22),y
	pha
	and #127
	jsr $ab47
	iny
	pla
	bpl j2
	jsr $a67a
	ldy $3a
	iny
	beq j1
	jsr $bdc2
j1	lda #<ok
	ldy #>ok
	jmp $a478