;:sys36864
	;.opt oo
	*= $c000
basend	=45
basanf	=43
start	=2064
twait	=146
tsys	=158
strout	=$ab1e
input	=$ffcf
cr	=$aad7
tmp	=251
fac	=$62
intflt	=$bc49
facasc	=$bddf
puffer	=$100
sysnum	=2054
	jmp run
routine	=*
lab1	lda #0
lab2	ldy #0
	sta basend
	sty basend+1
lab3	lda #0
lab4	ldy #0
	jsr strout
	jmp start
text	.byte "\x93"
dat1	.byte "......................... coming up"	;25
	.byt 13
	.byte "\x11programmed and designed"
	.byt 13
	.byte "by\xa0"
dat2	.byte "........................., "	;25
dat3	.byte "...."
	.byt 13,13
dat4	.byte "..................................."	;35
	.byt 13
	.byte "by nikolaus heusler,\xa0"
dat5	.byte "......"
	.byt 13,13
	.byte "(c)opyright "
dat6	.byte "........................."	;25
	.byt 13,13
	.byte "unpacking\x8e\x08 .. mompls .."
	brk
tit	.byt 13
	.byte "\x93nachbearbeiter fuer superpacker, v1.1"
	.byt 13
	.byte "\x11(c)opyright n. heusler, nh-060188-arr"
	.byt 13
	.byte "\x11          ein  nss-programm"
	.byt 13,13,0
testtab	.byt 14,8,$e8,$fd,tsys
	.byte "2064 sc"
	.byt 0,0,0
err1	.byte "kein superpacker-programm im speicher !"
	.byt 13,0
intext	.word ask1,ask2,ask3,ask4,ask5,ask6
ask1	.byte "programmname"
	brk
ask2	.byte "autor"
	brk
ask3	.byte "programmiert im jahr"
	brk
ask4	.byte "leistungen von nh"
	brk
ask5	.byte "bearbeitungsdatum"
	brk
ask6	.byte "copyrightvermerk"
	brk
maxlen	.byt 25,25,4,35,6,25
defatab	.word def1,def1,def3,def4,def5,def6
def3	.byte "1988"
def1	brk
def4	.byte "tested, revised, linked and packed"
	brk
def5	.byte "....88"
	brk
def6	.byte "markt & technik, 64'er"
	brk
reask	.byt 13
	.byte "\x91? "
	brk
askmark	.byte " ?"
	.byt 13,32,32,0
thertab	.word dat1,dat2,dat3,dat4,dat5,dat6
nr	brk
max	brk
fert	.byte "okay. bitte fertiges produkt mit 'save'"
	.byt 13
	.byte "abspeichern !\x11"
	brk
indat	txa
	asl
	pha
	tax
	lda intext+1,x
	tay
	lda intext,x
	jsr strout
	lda #<askmark
	ldy #>askmark
	jsr strout
	pla
	pha
	tax
	lda defatab+1,x
	tay
	lda defatab,x
	jsr strout
	lda #<reask
	ldy #>reask
	jsr strout
	pla
	tax
	lda thertab,x
	sta tmp
	lda thertab+1,x
	sta tmp+1
	ldx nr
	lda maxlen,x
	sta max
	ldy #0
inloop	jsr input
	cmp #13
	beq dr
	sta (tmp),y
	iny
	cpy max
	bcc inloop
dr	lda #"\x92"
dd	cpy max
	bcs fi
	sta (tmp),y
	iny
	bne dd
fi	jsr cr
	jmp cr
puch	ldy #0
	sta (basend),y
	inc basend
	bne nocarry
	inc basend+1
nocarry	rts
run	lda #<tit
	ldy #>tit
	jsr strout
	ldy #err1-testtab-1
testme	lda (basanf),y
	cmp testtab,y
	bne false
	dey
	bpl testme
	bmi right
false	lda #<err1
	ldy #>err1
	jmp strout
right	lda basend
	sta lab1+1
	clc
	adc #text-routine
	sta lab3+1
	lda basend+1
	sta lab2+1
	adc #0
	sta lab4+1
	ldx #0
	stx nr
datin	jsr indat
	inc nr
	ldx nr
	cpx #6
	bcc datin
	lda basend
	ldy basend+1
	sta fac+1
	sty fac
	ldx #$90
	sec
	jsr intflt
	jsr facasc
	ldx #0
tr	lda puffer,x
	beq et
	sta sysnum,x
	inx
	bne tr
et	lda #" "
	sta sysnum,x
	lda #twait
	sta sysnum+1,x
	cpx #5
	bcs no4
	lda #"!"
	sta sysnum+2,x
no4	ldx #0
tras	lda routine,x
	jsr puch
	inx
	cpx #tit-routine
	bcc tras
	lda #<fert
	ldy #>fert
	jmp strout