;:sys58451
sys36864
	;.opt oo
	*= $cd33
lvec	=$306
bvec	=$308
strout	=$ab1e
color	=646
oldbef	=$a7e7
tlist	=$9b
oldwarm	=$e38b
wvec	=$300
clist	=$a6f3
oldeing	=$a483
evec	=$302
remmod	=182
token	=181
ovec	=$326
oldout	=$f1ca
rein	lda #<neulist
	ldy #>neulist
	sta lvec
	sty lvec+1
	lda #<neubef
	ldy #>neubef
	sta bvec
	sty bvec+1
	lda #<neueing
	ldy #>neueing
	sta evec
	sty evec+1
	lda #<neuwarm
	ldy #>neuwarm
	sta wvec
	sty wvec+1
	lda #0
	sta 53280
	sta 53281
	lda #<hallo
	ldy #>hallo
	jmp strout
col1	.byt 12
col2	.byt 15
col3	.byt 7
col4	.byt 1
trenn	.byt 0
hallo	.byt 13
	.byte "\x99color-lister v1"
	.byt 13
	.byte "\x11von nikolaus heusler"
	.byt 13
	.byte "(c) nh-081290-arr"
	.byt 13,0
neubef	jsr 115
	cmp #tlist
	bne nolist
	ldx col1
	stx color
	ldx #0
	stx remmod
nolist	cmp #"!"
	beq change
	jsr 121
	jmp oldbef
change	jmp init
neuout	cmp #13
	bne nocr
	lda #0
	sta remmod
	lda col1
	sta color
	lda #13
nocr	jmp oldout
neuwarm	lda col3
	sta color
	lda #<neuout
	ldy #>neuout
	sta ovec
	sty ovec+1
	jmp oldwarm
neueing	lda col3
	sta color
	jmp oldeing
neulist	ldx remmod
	bne remakt
	tax
	bmi list2
list1	ldx col1
weitl	stx color
	jmp clist
list2	cmp #-1
	beq list1
	bit $f
	bmi list1
	sta token
	sec
	sbc #$7f
	tax
	sty $49
	ldy col2
	sty color
	ldy #-1
l1	dex
	beq l2
l3	iny
	lda $a09e,y
	bpl l3
	bmi l1
l2	iny
	lda $a09e,y
	pha
	and #$7f
	jsr $ab47
	pla
	bpl l2
	lda token
	cmp #143
	bne norem
	inc remmod
norem	lda trenn
	ldy $49
	bne list1
remakt	ldx col4
	bpl weitl
init	lda #<intxt
	ldy #>intxt
	jsr strout
	lda #13
	sta 211
	ldx col1
	jsr colout
	lda #13
	sta 211
	ldx col2
	jsr colout
	lda #13
	sta 211
	ldx col4
	jsr colout
	lda #13
	sta 211
	ldx col3
	jsr colout
	lda #14
	sta 211
	lda trenn
	beq aus
	lda #"n"
	ldx #32
	bne sat
aus	lda #"u"
	ldx #"s"
sat	jsr $ffd2
	txa
	jsr $ffd2
	lda #<hoch
	ldy #>hoch
	jsr strout
getpar	jsr 65508
	cmp #13
	bne noaus
	lda #13
	ldx #8
runter	jsr $ffd2
	dex
	bne runter
	jsr 115
	jmp $a7ae
noaus	cmp #"5"
	bne no5
	lda trenn
	eor #32
	sta trenn
	bpl init
no5	cmp #"1"
	bne no1
	inc col1
	lda col1
	and #15
	sta col1
qinit	jmp init
no1	cmp #"2"
	bne no2
	inc col2
	lda col2
	and #15
	sta col2
	bpl qinit
no2	cmp #"4"
	bne no3
	inc col3
	lda col3
	and #15
	sta col3
	bpl qinit
no3	cmp #"3"
	bne getpar
	inc col4
	lda col4
	and #15
	sta col4
	bpl qinit
colout	ldy #-1
	inx
c1	dex
	beq c3
c2	iny
	lda colors,y
	bmi c1
	bpl c2
c3	iny
	lda colors,y
	pha
	and #127
	jsr $ffd2
	pla
	bpl c3
	lda #32
c4	jsr $ffd2
	ldx 211
	cpx #37
	bcc c4
	jmp $aad7
intxt	.byt 13
	.byte "       text:"
	.byt 13
	.byte "      token:"
	.byt 13
	.byte "        rem:"
	.byt 13
	.byte "     ready.:"
	.byt 13
	.byte "leerzeichen: a"
	.byt 13
	.byte "\x11tasten: <1> bis <5> und <return>\x91"
hoch	.byte "\x91\x91\x91\x91\x91"
	brk
colors	.byte "schwarZweisSroTtuerkiSlilAgrueNblaUgelB"
	.byte "orangEbrauNhellroTdunkelgraUmittelgraUhellgrueN"
	.byte "hellblaUhellgraU"