;:sys36864
	*= $c000
	;.opt oo
;del routine
; del
; del nr
; del von-
; del von-bis
; del -bis
chrgot	=121
getline	=$a96b
chrget	=$73
byt	=$14
ptr	=$5f
token	=$ab 	; "-"
synerr	=$af08
mem	=2
basic	=$e385
binden	=$a533
lat	=247
end	=$2d
calc	=$a613
lat2	=lat+2
illquan	=$b248
zei	=34
clr	=$a659
	jsr $aefd
	jsr del
	jsr clr
	jmp basic
del	jsr chrgot
	bcc nozif
	beq nozif
	cmp #token
	bne syntax
nozif	jsr getline
	lda byt
	sta mem
	lda byt+1
	sta mem+1
	jsr chrgot
	beq noline
	cmp #token
	bne syntax
	jsr chrget
	jsr getline
	beq noline
syntax	jmp synerr
noline	lda byt
	ora byt+1
	bne nonull
	ldx #-1
	stx byt+1
	dex
	stx byt
nonull	jsr test
	inc byt
	bne nocy
	inc byt+1
nocy	jsr calc
	lda ptr
	sta lat
	lda ptr+1
	sta lat+1
	lda mem
	sta byt
	lda mem+1
	sta byt+1
	jsr calc
	lda ptr
	ldy #0
	sta lat2
	lda ptr+1
	sta lat2+1
haupt	lda lat+1
	cmp end+1
	bcc weit
	bne ende
	lda lat
	cmp end
	bcs ende
weit	lda (lat),y
	sta (lat2),y
	inc lat
	bne noi2
	inc lat+1
noi2	inc lat2
	bne haupt
	inc lat2+1
	clc
	bcc haupt
ende	lda #0
	sta (lat2),y
	iny
	sta (lat2),y
	jsr binden
	lda zei
	clc
	adc #2
	sta end
	lda zei+1
	adc #0
	sta end+1
	rts
test	lda mem+1
	cmp byt+1
	bne gro
	lda mem
	cmp byt
	beq ok
gro	bcc ok
	jmp illquan
ok	rts