;:sys36864
;"in anfuehrungszeichen !"
	;.opt oo
chkcom	=$aefd
flag	=247
buffer	=828
chrget	=115
ptr	=122
prgstart	=43
prg	=95
quote	=248
return	=$aad7
lnprint	=48589
chrgot	=121
	*= $8e00
	jsr chkcom
	beq nurkomma
	cmp #34
	beq string
	ldy #0
	sty flag
holtext	sta buffer,y
	iny
	jsr chrget
	bne holtext
	sta buffer,y
	beq voll
string	lda #-1
	sta flag
	ldy #1
holstr	lda (ptr),y
	beq stend
	cmp #34
	beq stend
	sta buffer-1,y
	iny
	bne holstr
stend	lda #0
	sta buffer-1,y
	jsr chrgot
	beq voll
suchend	jsr chrget
	bne suchend
voll	lda prgstart
	sta prg
	lda prgstart+1
	sta prg+1
line	ldy #1
	lda (prg),y
	bne goon
nurkomma	rts
goon	ldx #0
	stx quote
	ldy #4
search	lda (prg),y
	beq eoline
	cmp #34
	bne noquot
	lda #-1
	eor quote
	sta quote
noquot	lda quote
	cmp flag
	bne miss
	lda (prg),y
	cmp buffer,x
	bne miss
	inx
	lda buffer,x
	bne weitsuch
	jsr found
	jmp eoline
miss	ldx #0
weitsuch	iny
	jmp search
eoline	ldy #0
	lda (prg),y
	pha
	iny
	lda (prg),y
	sta prg+1
	pla
	sta prg
	jmp line
found	jsr return
	ldy #2
	lda (prg),y
	tax
	iny
	lda (prg),y
	jsr lnprint
	rts