;:sys36864
	;.opt oo
	*= 50112
v	=$d000
	jmp start
dauer	.byt 60
schnelle	.byt 4
wahrsch	.byt 15
higru	.byt 6
fisch	.byt 7
fit	.byt 13
	.byte "something smells in here...  fish!"
	.byt 13,13
	.byte "by nikolaus heusler   10.92"
	.byt 13
	.byte "   zwengauerweg  18"
	.byt 13
	.byte "   8000 muenchen 71"
	.byt 13,0
dez	.word 0
fi	.word 0,0
scrn	brk
dez2	brk
col0	brk
col1	brk
adm	brk
adr	.byt 192,64,128,192,2,3,3,3
gr	.byt 1,2,4,8
ugr	.byt 254,253,251,247
start	lda #<iq
	ldy #>iq
	sei
	sta 788
	sty 789
	lda dauer
	sta dez+1
	lda #60
	sta dez
	lda #0
	sta fi
	sta fi+1
	sta fi+2
	sta fi+3
	sta scrn
	lda #1
	sta dez2
	lda #<fit
	ldy #>fit
	jmp $ab1e
iq	jsr fish
	jmp $ea31
copy	sta 5
	ldx #4
	ldy #0
	sty 2
	sty 4
kopier	lda (2),y
	sta (4),y
	lda #32
	sta (2),y
	iny
	bne kopier
	inc 3
	inc 5
	dex
	bne kopier
	lda $d2
	jmp $e9f7
fish	lda #100
	sta 54287
	lda #129
	sta 54290
	lda 203
	eor #64
	ora 653
	beq standby
	lda #60
	sta dez
	lda dauer
	sta dez+1
	lda scrn
	bne waran
ret	rts
waran	lda #0
	sta scrn
	sta v+21
	sta v+16
	sta fi
	sta fi+1
	sta fi+2
	sta fi+3
	lda #1
	sta dez2
	lda col1
	sta 53281
	lda col0
	sta 53280
	lda adm
	sta 648
	ldx #204
	stx 3
	bne copy
standby	lda scrn
	bne party
	dec dez
	bne ret
	lda #60
	sta dez
	dec dez+1
	bne ret
	sta scrn
	lda 53281
	sta col1
	lda 53280
	sta col0
	lda higru
	sta 53280
	sta 53281
	lda 648
	sta adm
	sta 3
	lda #204
	sta 648
	jsr copy
party	dec dez2
	bne ret
	lda schnelle
	sta dez2
	lda 54299
	cmp wahrsch
	bcs move
	ldx #3
suchfrei	lda fi,x
	beq fund
	dex
	bpl suchfrei
	bmi move
fund	lda #1
	sta fi,x
	txa
	asl
	tay
suchy	lda 54299
	cmp #50
	bcc suchy
	cmp #230
	bcs suchy
	sta v+1,y
suchx	lda 54299
	cmp #13
	bcc suchx
	cmp #161
	bcs suchx
	asl
	sta v,y
	php
	lda v+16
	ora gr,x
	plp
	bcs set
	eor gr,x
set	sta v+16
	lda v+21
	ora gr,x
	sta v+21
	lda fisch
	sta v+39,x
move	lda #11
	sta 2040
	ldx #13
	stx 2041
	inx
	stx 2042
	inx
	stx 2043
	ldx #3
suchan	lda fi,x
	beq ruht
	cmp #9
	bne nosh
	txa
	asl
	tay
	lda v+1,y
	adc #1
	sta v+1,y
	lda v,y
	sec
	sbc #9
	sta v,y
	bcs ok
	lda v+16
	eor gr,x
	sta v+16
ok	lda #9
nosh	sec
	sbc #1
	ldy #0
	sty 3
	asl
	asl
	asl
	asl
	rol 3
	asl
	rol 3
	asl
	rol 3
	sta 2
	lda 3
	ora #192
	sta 3
	lda adr+4,x
	sta 5
	lda adr,x
	sta 4
	ldy #63
setspr	lda (2),y
	sta (4),y
	dey
	bpl setspr
	inc fi,x
	lda fi,x
	cmp #16
	bcc ruht
	lda #0
	sta fi,x
	lda v+21
	and ugr,x
	sta v+21
ruht	dex
	bpl suchan
	rts