;:sys36864
	*= $c000
	;.opt oo
	jmp start
row	.byt $ef,$7f,$7f,$fd,$fd,$fb,$fb,$f7,$f7,$ef
coln	.byt $f7,$fe,$f7,$fe,$f7,$fe,$f7,$fe,$f7,$fe
crev	.byt 1,0,0,0,0,1,1,1
cadd	.byt 160,0,128,224,32,160,96,224
tas1	=659
tas2	=660
tas3	=661
irq	jsr $ffea
	jsr crsr
	lda 198
	pha
	jsr $ea87
	lda 653
	cmp #6
	beq cbct
	pla
	lda tas1
	beq qioff
	lda #0
	sta tas1
	lda tas2
	tay
	lsr
	lsr
	lsr
	lsr
	lsr
	tax
	tya
	clc
	adc cadd,x
	ldy crev,x
	bne rvs
	ldx 198
	cpx $289
	bcs ioff
	sta $277,x
	inc 198
	bne ioff
rvs	ldx 198
	inx
	inx
	cpx $289
	bcs ioff
	ldx 198
	tay
	lda #18
	sta $277,x
	tya
	sta $278,x
	lda #146
	sta $279,x
	inc 198
	inc 198
	inc 198
qioff	jmp ioff
cbct	pla
	sta 198
	lda tas1
	bne cb1
	lda #0
	sta tas2
	inc tas1
cb1	ldx #9
cb2	lda row,x
	sta $dc00
	lda $dc01
	ora #%11110110
	cmp coln,x
	beq num
	dex
	bpl cb2
	lda #0
	sta tas3
	beq ioff
num	lda tas3
	bne ioff
	inc tas3
	lda tas2
	asl tas2
	asl tas2
	adc tas2
	asl
	sta tas2
	txa
	adc tas2
	sta tas2
ioff	jmp $ea7e
crsr	lda 646
	sta 53248+39
	lda 214
	asl
	asl
	asl
	adc #50
	sta 53249
	tsx
	lda 211
	cmp #40
	bcc *+4
	sbc #40
	asl
	asl
	asl
	php
	clc
	adc #24
	sta 53248
	lda #0
	bcs one
	plp
	bcs one
	.byt $2c
one	lda #1
	sta 53264
	txs
	lda #0
	sta $cf
	ldx $cc
	bne nocu
	dec $cd
	bne jacu
	lda #20
	sta $cd
	lda 53269
	eor #1
nocu	sta 53269
	sta 53248+27
jacu	rts
start	lda #4
	sta 648
	jsr 65409
	sei
	lda #0
	sta 56576
	lda #196
	sta 648
	lda #25
	sta 53272
	lda #15
	sta 53280
	sta 53281
	lda #11
	sta 646
	lda #<irq
	ldy #>irq
	sta 788
	sty 789
	lda #0
	sta tas1
	sta tas2
	ldx #64
clrsp	sta $e800,x
	dex
	bpl clrsp
	lda #-1
	ldx #7
	ldy #0
sesp	sta $e800,y
	iny
	iny
	iny
	dex
	bpl sesp
	cli
	ldx #0
cf	lda fo,x
	sta $e000,x
	lda fo+256,x
	sta $e100,x
	lda fo+$200,x
	sta $e200,x
	lda fo+$300,x
	sta $e300,x
	lda fo+$400,x
	sta $e400,x
	lda fo+$500,x
	sta $e500,x
	lda fo+$600,x
	sta $e600,x
	lda fo+$700,x
	sta $e700,x
	dex
	bne cf
	lda #160
	sta 51192
	lda #96
	sta cf
	jmp $e544
fo	=*