;:sys36864
	;.opt oo
loadvkt	=$330
savevkt	=$332
sa	=$b9
openiec	=$f3d5
ga	=$ba
talk	=$ed09
sectalk	=$edc7
getiec	=$ee13
ptr	=$ae
status	=144
untalk	=$edef
closefile	=$f642
contload	=$f5a9
strout	=$ab1e
prgstrt	=43
prgend	=45
search	=$f5af
loading	=$f5d2
saving	=$f68f
send	=$eddd
tmp	=$ac
incadr	=$fcdb
contsave	=$f63f
listen	=$ed0c
seclist	=$edb9
setptr	=$fb8e
testend	=$fcd1
	*= $c000
init	lda #<loadneu
	ldy #>loadneu
	sta loadvkt
	sty loadvkt+1
	lda #<saveneu
	ldy #>saveneu
	sta savevkt
	sty savevkt+1
	lda #<mess
	ldy #>mess
	jmp strout
mess	.byte "new load and save ok."
	.byt 0
temp	.byt 0
loadneu	lda #0
	sta status
	ldx sa
	jsr search
	lda #$60
	sta sa
	jsr openiec
	lda ga
	jsr talk
	lda sa
	jsr sectalk
	jsr getiec
	jsr getiec
	lda prgstrt
	ldy prgstrt+1
	sta ptr
	sty ptr+1
	lda #0
	sta temp
	jsr loading
	lda #$fd
	and status
	sta status
loadloop	jsr getiec
	sec
	sbc temp
	inc temp
	ldy #0
	sta (ptr),y
	inc ptr
	bne noinc
	inc ptr+1
noinc	bit status
	bvc loadloop
	jsr untalk
	jsr closefile
	jmp contload
saveneu	lda #$61
	sta sa
	lda #0
	sta temp
	jsr openiec
	jsr saving
	lda ga
	jsr listen
	lda sa
	jsr seclist
	ldy #0
	jsr setptr
	lda tmp
	jsr send
	lda tmp+1
	jsr send
saveloop	jsr testend
	bcs ready
	lda (tmp),y
	clc
	adc temp
	inc temp
	jsr send
	jsr incadr
	bne saveloop
ready	jmp contsave