;:sys36864
	;.opt oo
	*= 50000
t	=2
x1	=3
x2	=4
y1	=5
y2	=6
re	=180
dx	=181
dy	=182
li	=166
xa	=167
ya	=168
ls	=251
lm	=252
joy	=250
	jmp start
	jmp stun
	jmp minu
	jmp clr
grbit	.byt 128,64,32,16,8,4,2,1
hx	.byt 10,13,16,17,16,13,10,7,4,3,4,7
mx	.byt 10,11,12,13,14,15,16,17,17,18,19
	.byt 19,20,20,20,20,20,20,20,19,19,18,17,17
	.byt 16,15,14,13,12,11,10,9,8,7,6,5,4,3,3
	.byt 2,1,1,0,0,0,0,0,0,0,1,1,2,3,3,4,5,6,7,8,9
blatt	.byt 0,254,0,3,255,128,15,255,224,31,255
	.byt 240,31,255,240,63,255,248,63,255,248,127
	.byt 255,252,127,255,252,127,239,252,127,199
	.byt 252,127,239,252,127,255,252,127,255,252
	.byt 63,255,248,63,255,248,31,255,240,31,255
	.byt 240,15,255,224,3,255,128,0,254,0
hi	.byte "\x9emini-uhr v1.0 installiert"
	.byt 13
	.byte "\x11(c) nikolaus heusler 5.91"
	.byt 13,0
start	lda #127
	sta $dd0f
	jsr 121
	beq run
	jsr $aefd
	jsr $ad9e
	jsr $b6a3
	cmp #4
	beq ok4
ill	jmp $b248
ok4	ldy #0
	lda (34),y
	sec
	sbc #"0"
	cmp #3
	bcs ill
	asl
	asl
	asl
	asl
	sta t
	iny
	lda (34),y
	sec
	sbc #"0"
	cmp #10
	bcs ill
	ora t
	bne no0
	lda #$12
no0	cmp #$24
	bcs ill
	cmp #$13
	bcc set1
	sei
	sec
	sed
	sbc #$12
	cld
	cli
set1	sta $dd0b
	iny
	lda (34),y
	sec
	sbc #"0"
	cmp #6
	bcs ill
	asl
	asl
	asl
	asl
	sta t
	iny
	lda (34),y
	sec
	sbc #"0"
	cmp #10
	bcs ill
	ora t
	sta $dd0a
	lda #0
	sta $dd09
	sta $dd08
run	jsr 65409
	lda #3
	sta 53269
	lda #229
	sta lm
	sta ls
	sta 53249
	sta 53251
	lda #11
	sta 2040
	sei
	lda #<irq
	ldy #>irq
	sta 788
	sty 789
	cli
	lda #0
	sta 56584
	lda #128
	sta $dd0e
	ldx #62
	lda #3
	sta 53264
copy	lda blatt,x
	sta 832,x
	dex
	bpl copy
	lda #13
	sta 2041
	lda #65
	sta 53250
	lda #1
	sta 53248+40
	lda #64
	sta 53248
	lda #0
	sta 53248+39
	sta 53280
	lda #6
	sta 53281
	lda #<hi
	ldy #>hi
	jmp $ab1e
irq	lda $dd0a
	cmp lm
	beq min
	sta lm
	jsr clr
min	lda $dd0a
	jsr convert
	jsr minu
	lda $dd0b
	and #127
	jsr convert
	jsr stun
	lda $dd09
	cmp ls
	beq sek
	lda ls
	jsr convert
	jsr seku
	jsr unplot
sek	lda $dd09
	sta ls
	jsr convert
	jsr seku
	jsr plot
	lda 56584
	lda 56320
	and #31
	sta joy
	and #1
	bne no1
	lda 53249
	cmp #51
	bcc no1
	dec 53249
	dec 53251
no1	lda joy
	and #2
	bne no2
	lda 53249
	cmp #229
	bcs no2
	inc 53249
	inc 53251
no2	lda joy
	and #4
	bne no4
	lda 53264
	and #1
	bne left
	lda 53248
	beq no4
left	lda 53248
	sec
	sbc #1
	sta 53248
	bcs le1
	lda 53264
	and #254
	sta 53264
le1	lda 53250
	sec
	sbc #1
	sta 53250
	bcs no4
	lda 53264
	and #253
	sta 53264
no4	lda joy
	and #8
	bne no8
	lda 53264
	and #1
	beq right
	lda 53248
	cmp #64
	bcs no8
right	inc 53248
	bne ri1
	lda 53264
	ora #1
	sta 53264
ri1	inc 53250
	bne no8
	lda 53264
	ora #2
	sta 53264
no8	jmp 59953
plot	sty t
	tya
	asl
	adc t
	sta t
	txa
	lsr
	lsr
	lsr
	clc
	adc t
	tay
	txa
	and #7
	tax
	lda grbit,x
	ora 704,y
	sta 704,y
	rts
unplot	sty t
	tya
	asl
	adc t
	sta t
	txa
	lsr
	lsr
	lsr
	clc
	adc t
	tay
	txa
	and #7
	tax
	lda grbit,x
	eor #-1
	and 704,y
	sta 704,y
	rts
line	lda #10
	sta y1
	lda #12
	sta x1
	lda x2
	sec
	sbc x1
	sta dx
	lda y2
	sec
	sbc y1
	sta dy
	ldy #1
	sty xa
	sty ya
	ldx #-1
	lda dx
	bpl li1
	stx xa
	lda dx
	eor #-1
	clc
	adc #1
	sta dx
li1	lda dy
	bpl li2
	stx ya
	lda dy
	eor #-1
	clc
	adc #1
	sta dy
li2	stx li
	lda dx
	cmp dy
	bcc li5
	sty li
li5	stx re
	lda dx
	bne li3
	sta re
li3	ldx x1
	ldy y1
	jsr plot
li7	lda y1
	cmp y2
	bne li4
	lda x1
	cmp x2
	bne li4
	rts
li4	lda re
	bmi li6
	sec
	sbc dx
	sta re
	lda y1
	clc
	adc ya
	sta y1
	lda li
	bpl li7
	bmi li3
li6	clc
	adc dy
	sta re
	lda x1
	clc
	adc xa
	sta x1
	lda li
	bmi li7
	bpl li3
stun	lda hx,y
	clc
	adc #2
	sta x2
	tya
	clc
	adc #3
	cmp #12
	bcc oks
	sbc #12
oks	tay
	lda hx,y
all	eor #-1
	clc
	adc #21
	sta y2
	jmp line
minu	lda mx,y
	clc
	adc #2
	sta x2
	tya
	clc
	adc #15
	cmp #60
	bcc okm
	sbc #60
okm	tay
	lda mx,y
	bpl all
seku	lda mx,y
	clc
	adc #2
	tax
	tya
	clc
	adc #15
	cmp #60
	bcc okd
	sbc #60
okd	tay
	lda mx,y
	eor #-1
	clc
	adc #21
	tay
	rts
clr	ldx #63
	lda #0
cl	sta 704,x
	dex
	bpl cl
	rts
convert	tax
	lsr
	lsr
	lsr
	lsr
	asl
	sta t
	asl
	asl
	adc t
	sta t
	txa
	and #15
	clc
	adc t
	tay
	rts