;:sys36864
	;.opt oo
	*= $c000
tmp	=43
pag	=648
irqvec	=788
bild	=$d1
farb	=$f3
farbram	=$ea24
curs	=$cf
tmp2	=45
strout	=$ab1e
time1	=20
time2	=40
v	=53248
ptr	=2040
ort	=704
init	sei
	lda irqvec+1
	cmp #>neuirq
	beq sat
	sta oldirq+2
	lda irqvec
	sta oldirq+1
	lda #<neuirq
	ldy #>neuirq
	sta irqvec
	sty irqvec+1
	lda #time1
	sta mode+1
	lda #0
	sta art
	sec
	ror oft
	lda #<nanu
	ldy #>nanu
	jsr strout
sat	cli
	rts
neuirq	jsr irq
	jsr down
oldirq	jmp 0
nanu	.byt 13
	.byte "whatever you'll see: don't panic. every-"
	.byte "thing is under control.\x11"
	brk
pos1	brk
pos2	brk
oft	brk
mode	.word 0
art	brk
irq	lda art
	beq irq2
	dec mode
	bne back
	lda #44
	sta oft
	lda #time2
	sta mode+1
	lda #0
	sta art
irq2	dec mode
	bne back
	dec mode+1
	bne back
	inc art
	lda #1
	sta v+21
	lda #0
	sta v+23
	sta v+29
	sta v+28
	sta v+16
	lda #181
	sta v
	lda #229
	sta v+1
	lda #1
	sta v+39
	ldx #63
copy	lda muell,x
	sta ort,x
	dex
	bpl copy
	lda #11
	sta ptr
back	rts
down	lda oft
	bmi weg
qdown	lda bild
	pha
	lda bild+1
	pha
	lda farb
	pha
	lda farb+1
	pha
	lda tmp
	pha
	lda tmp+1
	pha
	lda tmp2
	pha
	lda tmp2+1
	pha
an	dec oft
	jsr schieb
	jsr rechts
	jsr unglaube
	lda oft
	bpl an
	pla
	sta tmp2+1
	pla
	sta tmp2
	pla
	sta tmp+1
	pla
	sta tmp
	pla
	sta farb+1
	pla
	sta farb
	pla
	sta bild+1
	pla
	sta bild
	lda #0
	sta v+21
weg	rts
schieb	lda #<980
	sta bild
	lda pag
	clc
	adc #>980
	sta bild+1
	jsr farbram
	ldy #0
	lda (bild),y
	sta pos1
	iny
	lda (bild),y
	sta pos2
	ldx #23
loop	lda bild
	sec
	sbc #40
	sta tmp
	lda bild+1
	sbc #0
	sta tmp+1
	lda farb
	sec
	sbc #40
	sta tmp2
	lda farb+1
	sbc #0
	sta tmp2+1
	ldy #1
loop2	lda (tmp),y
	sta (bild),y
	lda (tmp2),y
	sta (farb),y
	dey
	bpl loop2
	lda tmp
	sta bild
	lda tmp+1
	sta bild+1
	lda tmp2
	sta farb
	lda tmp2+1
	sta farb+1
	dex
	bpl loop
	lda #32
	iny
	sta (bild),y
	iny
	sta (bild),y
	rts
rechts	lda #0
	sta bild
	lda pag
	sta bild+1
	ldx #24
rech	jsr farbram
	ldy #20
	lda (bild),y
	cmp #32
	bne dawa
rere	dey
	lda (bild),y
	iny
	sta (bild),y
	dey
	lda (farb),y
	iny
	sta (farb),y
	dey
	bne rere
	lda #" "
	sta (bild),y
dawa	ldy #21
	lda (bild),y
	cmp #32
	bne wada
lili	iny
	lda (bild),y
	dey
	sta (bild),y
	iny
	lda (farb),y
	dey
	sta (farb),y
	iny
	cpy #39
	bcc lili
	lda #" "
	sta (bild),y
wada	lda bild
	clc
	adc #40
	sta bild
	lda bild+1
	adc #0
	sta bild+1
	dex
	bpl rech
	rts
unglaube	lda pos1
	cmp #32
	bne aha
	lda pos2
	cmp #32
	bne aha
	rts
aha	lda #44
	sta oft
	rts
muell	=*