;:sys36864
	;.opt oo
	*= $c000
tab	=$e000
taba	=tab+64
tabx	=taba+32
taby	=tabx+32
tabs	=taby+32
tabp	=tabs+32
stackt	=$e100
t	=2
u	=t+1
	jmp set
	jmp off
	jmp speed
set	sei
	lda #0
	ldy #>tab
	sta t
	sty u
	sta bas
	sta anz
	sta first
getpar	jsr 121
	beq end
	cmp #","
	beq komma
	jmp $af08
komma	jsr $aefd
	jsr 121
	cmp #"&"
	beq basic
	jsr $ad8a
	jsr $b7f7
	ldy #0
	lda $14
	ora $15
	beq ill
	lda $14
	sta (t),y
	inc t
	lda $15
	sta (t),y
	inc t
	inc anz
	lda anz
	cmp #31
	bcs ill
	bcc getpar
basic	jsr 115
	inc bas
	bne getpar
end	lda #0
	tay
	sta (t),y
	iny
	sta (t),y
	lda anz
	beq ill
	sei
	lda #<formirq
	ldy #>formirq
	sta $314
	sty $315
	lda #<formnmi
	ldy #>formnmi
	sta $fffa
	sty $fffb
	lda #0
	sta t
	cli
baswart	lda bas
	beq baswart
	rts
ill	jmp $b248
off	sei
	jsr 65418
	cli
	rts
speed	jsr 121
	beq norm
	jsr $b7f1
	.byt $2c
norm	ldx #60
	stx 56325
	rts
dahin	jmp dahin
dort	=dahin-1
formirq	lda 1
	sta jk+1
	lda #48
	sta 1
formlp	ldy #0
	lda (t),y
	iny
	ora (t),y
	bne weiter
	sty first
	dey
	sty t
	beq formlp
weiter	dey
	lda (t),y
	sta jl+1
	iny
	lda (t),y
	sta jh+1
	tsx
	lda $105,x
	ldy #0
	sta (t),y
	iny
	lda $106,x
	sta (t),y
	lda t
	lsr
	tay
	lda taba,y
	sta ja+1
	lda tabx,y
	sta jx+1
	lda taby,y
	sta jy+1
	lda tabs,y
	sta js+1
	lda tabp,y
	sta jp+1
	lda $101,x
	sta taby,y
	lda $102,x
	sta tabx,y
	lda $103,x
	sta taba,y
	lda $104,x
	sta tabs,y
	txa
	sta tabp,y
	lda t
	sta jt+1
	clc
	adc #>stackt
	sta u
	ldy #0
	sty t
dupst	lda (t),y
	sta jr+1
	lda $100,y
	sta (t),y
jr	lda #0
	sta $100,y
	iny
	bne dupst
jt	lda #0
	sta t
	lsr
	tay
	inc t
	inc t
	lda #>tab
	sta u
jp	ldx #0
	txs
	lda first
	bne jh
	ldx #247
	txs
	lda #>dort
	sta $108,x
	lda #<dort
	sta $107,x
jh	lda #0
	sta $106,x
jl	lda #0
	sta $105,x
js	lda #0
	sta $104,x
ja	lda #0
	sta $103,x
jx	lda #0
	sta $102,x
jy	lda #0
	sta $101,x
jk	lda #0
	sta 1
	jmp $ea31
formnmi	lda #55
	sta 1
	jmp ($fffa)
bas	brk
anz	brk
first	brk