;:sys36864
	;.opt oo
	*= 52000
	jmp run1
	jmp run2
getx	=$b7f1
run1	lda #<hi
	ldy #>hi
	jmp $ab1e
hi	.byte "\x11perforations-ueberspringer mps 803"
	.byt 13
	.byte "\x11(c) nh-310390-arr  (v2: 12.90)"
	.byt 13
	.byte "\x11sys 52003,a,b"
	.byt 13
	.byte "\x11 a = adresse (4 = drucker)"
	.byt 13
	.byte " b = zeilen pro seite:"
	.byt 13
	.byte "     6 lpi: 72"
	.byt 13
	.byte "     8 lpi: 96"
	.byt 13
	.byte " dot image: 123\x11"
	.byt 13
	.byte "vorher druckkopf auf perforation bringen"
	brk
adr	brk
lps	brk
chr	brk
lin	brk
run2	jsr getx
	stx adr
	jsr getx
	txa
	sec
	sbc #5
	sta lps
	lda #<neu
	ldy #>neu
	sta $326
	sty $327
	jsr init
	jmp 57741
neu	pha
	lda $9a
	cmp adr
	beq aha
	jmp $f1cd
aha	pla
	sta chr
	pha
	txa
	pha
	tya
	pha
	lda chr
	jsr wert
	pla
	tay
	pla
	tax
	pla
	clc
	rts
wert	cmp #13
	beq cr
	jmp $f1ca
cr	jsr $f1ca
	inc lin
	lda lin
	cmp lps
	bcs skip
	rts
skip	lda #13
	jsr $f1ca
	jsr $f1ca
	jsr $f1ca
linie	lda #1
	sta lin
	lda #"-"
	ldx #10
trenn	jsr $f1ca
	dex
	bne trenn
	lda #13
	jsr $f1ca
	jsr $f1ca
	jmp $f1ca
init	ldx adr
	lda #1
	ldy #0
	jsr $ffba
	tya
	jsr $ffbd
	lda #1
	pha
	jsr $ffc3
	pla
	jsr $ffc0
	ldx #1
	jsr $ffc9
	jsr linie
	jsr $ffcc
	lda #1
	jmp $ffc3