;:sys36864
	;.opt oo
	*= $cedf
	lda #<fra
	ldy #>fra
	jsr $ab1e
	ldx #0
getk	jsr $ffcf
	cmp #13
	beq cr
	sta 820,x
	inx
	bne getk
cr	lda #0
	sta 820,x
	tax
	stx 2
calc	lda 820,x
	beq fertig
	lda 2
	asl
	asl
	adc 2
	asl
	sta 2
	lda 820,x
	and #15
	clc
	adc 2
	sta 2
	inx
	bne calc
fertig	jsr $aad7
	ldy #$c
	jsr $f12f
	jsr $aad7
	jsr $aad7
	ldy #0
	sty 3
	lda #4
	sta 4
	lda #48
	sei
	sta 1
such	ldy #0
	lda (3),y
	cmp #$c6
	beq zerop
	cmp #$ce
	beq absol
weiter	inc 3
	bne such
	inc 4
	bne such
	lda #55
	sta 1
	cli
	rts
zerop	iny
	lda (3),y
	cmp #2
	beq weiter
	tax
	lda 0,x
	cmp 2
	bne weiter
	lda #165
found	pha
	lda #55
	sta 1
	ldy #4
poout	lda pot,y
	jsr $ffd2
	dey
	bpl poout
	ldx 3
	lda 4
	jsr $bdcd
	lda #","
	jsr $ffd2
	pla
	pha
	tax
	lda #0
	jsr $bdcd
	jsr $ab3f
	jsr $ffd2
	jsr $ffd2
	lda #"$"
	jsr $ffd2
	lda 4
	jsr hex
	lda 3
	jsr hex
	jsr $ab3f
	pla
	jsr hex
	jsr $aad7
	lda #48
	sei
	sta 1
	jmp weiter
absol	iny
	lda (3),y
	sta 5
	iny
	lda (3),y
	sta 6
	ldy #0
	lda (5),y
	cmp 2
	bne weiter
	lda #173
	bne found
hex	pha
	lsr
	lsr
	lsr
	lsr
	jsr hex1
	pla
hex1	and #15
	tax
	lda hext,x
	jmp $ffd2
fra	.byt 13
	.byte "how many lives now? 3\x9d"
	brk
pot	.byte " ekop"
hext	.byte "0123456789abcdef"