;:sys36864
	*= $c000
	;.opt oo
bsout	=$ffd2
tmp	=2
cr	=13
cint	=65409
vic	=$d000
return	=$aad7
satcr	=$e56a
zeile	=214
spalte	=211
zahl	=$100
floatasc	=$bddf
fac	=$62
intfloat	=$bc49
striout	=$ab1e
ay10	=$bf0c
tmp2	=4
konf	=1
spptr	=2040
key	=198
get	=65508
krepeat	=650
zn	=10
clrx	=59903
	jmp losgehts
hi	.byte "\x1a\x93\x12\x9anss animationsmaker: sequenzen erstellen"
	.byte "(c) nss 220387 version 1.0\x19\x0e \x1a"
	.byte "   \x99\xb0\x19\x06\xc0\xae\x19\x05 \xb0\x19\x06\xc0\xae\x19\x05 \xb0\x19\x06\xc0\xae\x1a"
	.byte "   \xdd\x19\x06 B\x19\x05 B\x19\x06 B\x19\x05 \xdd\x19\x06 \xdd\x1a"
	.byte "   \xdd\x19\x06 B\x9e   \x12\xdf\x92 \x99B\x19\x06 B\x9e   \x12\xdf\x92 \x99\xdd\x19\x06 \xdd\x1a"
	.byte "   \xdd\x19\x06 B\x9e\x12\x19\x04 \xdf\x92\x99B\x19\x06 B\x9e\x12\x19\x04 \xdf\x92\x99\xdd\x19\x06 \xdd\x1a"
	.byte "   \xdd\x19\x06 B\x9e\x12\x19\x04 \x92\xa9\x99B\x19\x06 B\x9e\x12\x19\x04 \x92\xa9\x99\xdd\x19\x06 \xdd\x1a"
	.byte "   \xdd\x19\x06 B\x9e   \xa9 \x99B\x19\x06 B\x9e   \xa9 \x99\xdd\x19\x06 \xdd\x1a"
	.byte "   \xad\x19\x06\xc0\xbd\x19\x05 \xad\x19\x06\xc0\xbd\x19\x05 \xad\x19\x06\xc0\xbd\x1a"
	.byte "\x19\x04 anfang\x19\x07 aktuel.\x19\x07 ende\x1a\x19\x04\x11\x9a\x12\x19( \x1a"
	.byte "\x1f \x12+,-\x92 sprite +/- 1   \x12>,<\x92 sprite +/- 10"
	.byte "\x1a \x12a\x92 anfang setzen\x19\x04 \x12e\x92 ende setzen"
	.byte "\x1a \x12m\x92 multi/hires\x19\x06 \x12q\x92 ende"
	.byte "\x1a \x12t\x92 test\x03"
hi2	.byte "\x13\x19\x11\x11\x1f \x12z\x92 (anti)zyklisch   \x12q\x92 menue"
	.byte "\x1a \x12+/-\x92 geschwin.\x19\x06 \x12r\x92 richtung\x03"
numspr	.byte "\x97\x92nr.\x03"
adrspr	.byte "@:\x03"
koord	.byt 3,16,29
mmlo	.byt 64,128,192
uslen	brk
num0	.word 272
num1	.word 0
num2	.word 287
spnum	brk
dir	brk
speed	.byt 19
mode	brk
strout	tax
	lda tmp
	pha
	lda tmp+1
	pha
	stx tmp
	sty tmp+1
slp	ldy #0
	lda (tmp),y
	beq fint
	cmp #"\x03"
	beq fint
	cmp #"\x1a"
	bne ncr
	lda #cr
ncr	cmp #"\x19"
	beq repeat
	jsr bsout
	inc tmp
	bne slp
	inc tmp+1
	bne slp
fint	pla
	sta tmp+1
	pla
	sta tmp
	rts
repeat	iny
	lda (tmp),y
	tax
	iny
	lda (tmp),y
rep	jsr bsout
	dex
	bne rep
	lda #3
	clc
	adc tmp
	sta tmp
	bcc slp
	inc tmp+1
	bne slp
outnumx	stx spnum
	lda koord,x
	sta spalte
	pha
	ldy #12
	jsr satcr
	lda #<numspr
	ldy #>numspr
	jsr strout
	lda spnum
	asl
	tay
	ldx num0,y
	lda num0+1,y
	ldy #5
	jsr using
	jsr return
	pla
	sta spalte
	ldy #13
	jsr satcr
	lda #<adrspr
	ldy #>adrspr
	jsr strout
	ldy #6
	lda spnum
	asl
	tax
	lda num0,x
	sta tmp
	lda num0+1,x
	sta tmp+1
mal64	asl tmp
	rol tmp+1
	dey
	bne mal64
	ldy #6
	ldx tmp
	lda tmp+1
	jmp using
akt3	lda num0
	ldy num0+1
	ldx #0
	jsr ayinx
	lda num2
	ldy num2+1
	ldx #2
	jsr ayinx
akt1	lda num1
	ldy num1+1
	ldx #1
ayinx	sta tmp
	sty tmp+1
	ldy #6
ml64	asl tmp
	rol tmp+1
	dey
	bne ml64
	lda mmlo,x
	sta tmp2
	lda #3
	sta tmp2+1
	ldy #63
	sei
	lda #48
	sta konf
transto	lda (tmp),y
	sta (tmp2),y
	dey
	bpl transto
	lda #55
	sta konf
	cli
	rts
using	sty uslen
	stx fac+1
	sta fac
	ldx #144
	sec
	jsr intfloat
	jsr floatasc
	ldx #0
find0	lda zahl,x
	beq found0
	inx
	bne find0
found0	cpx uslen
	beq starve
	ldy uslen
transzl	lda zahl,x
	sta zahl,y
	dey
	dex
	bpl transzl
	lda #32
fuellauf	sta zahl,y
	dey
	bpl fuellauf
starve	jsr ay10
	jmp striout
losgehts	jsr cint
	ldy #0
	sty vic+32
	sty vic+33
	dey
	sty krepeat
mama	lda #<hi
	ldy #>hi
	jsr strout
	lda #7
	sta vic+21
	sta vic+23
	sta vic+29
	lda #56
	sta vic
	lda #81
	sta vic+1
	sta vic+5
	sta vic+3
	lda #160
	sta vic+2
	ldy #1
	sty vic+40
	sty vic+41
	iny
	sty vic+37
	iny
	sty vic+38
	lda #8
	sta vic+4
	lsr
	sta vic+16
	ldx #0
	jsr outnumx
	ldx #1
	jsr outnumx
	ldx #2
	jsr outnumx
	jsr akt3
	lda #15
	ldy #2
setpt	sta spptr,y
	sec
	sbc #1
	dey
	bpl setpt
	iny
	sty key
menue	jsr get
	beq menue
	cmp #"q"
	bne noend
	jmp cint
noend	cmp #"+"
	bne nopos
	inc num1
	bne show
	inc num1+1
show	lda num1+1
	and #3
	sta num1+1
	jsr akt1
	ldx #1
	jsr outnumx
	jmp menue
nopos	cmp #"-"
	bne noneg
	dec num1
	ldy num1
	iny
	bne show
	dec num1+1
	jmp show
noneg	cmp #","
	bne nomin10
	lda num1
	sec
	sbc #zn
	sta num1
	lda num1+1
	sbc #0
	sta num1+1
	jmp show
nomin10	cmp #"."
	bne nopl10
	lda num1
	clc
	adc #zn
	sta num1
	bcc show
	inc num1+1
	bne show
nopl10	cmp #"m"
	bne nom
	lda vic+28
	eor #7
	sta vic+28
	jmp menue
nom	cmp #"e"
	bne noe
	lda num1
	ldy num1+1
	sta num2
	sty num2+1
	ldx #2
	bne awertae
noe	cmp #"a"
	bne noa
	lda num1
	ldy num1+1
	sta num0
	sty num0+1
	ldx #0
awertae	jsr outnumx
	jsr akt3
	jmp menue
noa	cmp #"t"
	bne not
	jsr test
	jmp mama
not	jmp menue
test	ldx #17
clr1	jsr clrx
	inx
	cpx #21
	bcc clr1
	lda #<hi2
	ldy #>hi2
	jsr strout
	lda #0
	sta dir
	sta key
	lda num0
	ldy num0+1
	sta num1
	sty num1+1
tmen	jsr akt1
	ldx #1
	jsr outnumx
	jsr texec
	jsr get
	beq tmen
	cmp #"q"
	bne noq
	rts
noq	cmp #"z"
	bne noz
	lda mode
	eor #-1
	sta mode
	jmp tmen
noz	cmp #"+"
	bne nospp
	lda speed
	beq tmen
	dec speed
	bpl tmen
nospp	cmp #"-"
	bne nomi
	lda speed
	bmi tmen
	inc speed
	bne tmen
nomi	cmp #"r"
	bne tmen
	lda dir
	eor #-1
	sta dir
	jmp tmen
texec	lda dir
	bne rueckw
	inc num1
	bne tex
	inc num1+1
	jmp tex
rueckw	dec num1
	ldy num1
	iny
	bne tex
	dec num1+1
tex	lda num1
	cmp num0
	bne test2
	lda num1+1
	cmp num0+1
	bne test2
	beq turn2
turn	lda dir
	eor #-1
	sta dir
	jmp goont
test2	lda num2
	cmp num1
	bne goont
	lda num2+1
	cmp num1+1
	beq turn2
goont	ldx speed
	beq tb
	ldy #0
sam	dey
	bne sam
	dex
	bne sam
tb	rts
turn2	lda mode
	beq turn
	jsr goont
	jsr akt1
	ldx #1
	jsr outnumx
	lda dir
	bmi set1
	lda num0
	ldy num0+1
	bpl set2
set1	lda num2
	ldy num2+1
set2	sta num1
	sty num1+1
	jmp goont