;:sys36864
	;.opt oo
	*= $8000
b	=820
	jsr $ffe7
	ldx #4
	txa
	ldy #7
	jsr $ffba
	lda #0
	jsr $ffbd
	txa
	jsr $ffc0
	lda #<hi
	ldy #>hi
	jmp ne1
hi	.byte "\x11\x0e\x08Druckprogramm fuer Vizawrite-Files"
	.byt 13
	.byte "Bitte vorher ggf. 'Unterlaengen' akti-  vieren!"
	.byt 13
	.byte "(c) nh-290391-arr V1.1"
	.byt 13
	.byte "\x11Name Vizawrite-File ? "
	brk
ne1	jsr $ab1e
	ldx #0
ne2	jsr 65487
	cmp #13
	beq ne3
	sta 704,x
	inx
	bne ne2
ne3	txa
	ldx #<704
	ldy #>704
	jsr $ffbd
	jsr breite
	ldx #8
	lda #1
	ldy #0
	sty 182
	jsr $ffba
	jsr $aad7
	lda #1
	jsr $ffc0
	ldx #1
	jsr $ffc6
	lda #201
	sta 2
	sta 3
ne4	jsr 65508
	dec 2
	bne ne4
ha1	lda 144
	ora 182
	bne textende
	jsr 65508
	cmp #$e6
	bne ha2
ha3	jsr 65508
	cmp #220
	beq ha1
	cmp #-1
	bne ha3
textende	jsr $aad7
	jsr $ffcc
	lda #4
	jsr $ffc3
	lda #1
	jmp $ffc3
ha2	cmp #220
	bne ha4
	lda #13
	bne ou1
ha4	cmp #101
	bne ha5
	lda #123
	bne ou1
ha5	cmp #118
	bne ha6
	lda #124
	bne ou1
ha6	cmp #120
	bne ha7
	lda #125
	bne ou1
ha7	cmp #121
	bne ha8
	lda #91
	bne ou1
ha8	cmp #122
	bne ha9
	lda #92
	bne ou1
ha9	cmp #123
	bne haa
	lda #93
	bne ou1
haa	cmp #124
	bne hab
	lda #126
	bne ou1
hab	cmp #32
	bcs hac
	ora #64
	bne ou1
hac	cmp #64
	bcc ou1
	cmp #91
	bcs had
	ora #128
	bne ou1
had	cmp #-1
	beq textende
	bne qha1
ou1	ldx 2
	cmp #32
	bne ou3
	stx 3
ou3	cmp #13
	beq ou4
	sta b,x
	inx
	stx 2
	cpx 181
	bcs ou2
qha1	jmp ha1
ou2	lda #0
	ldx 3
	bmi ou6
	sta b,x
	jsr out
	ldx 3
	ldy #-1
ww1	inx
	iny
	lda b,x
	sta b,y
	cpx 2
	bcc ww1
ou5	sty 2
	lda #-1
	sta 3
	bne qha1
ou4	lda #0
	sta b,x
	jsr out
	ldy #0
	beq ou5
ou6	ldx 181
	stx 3
	bne ou2
breite	lda #<br1
	ldy #>br1
	bne br2
br1	.byt 13
	.byte "\x11Textbreite ? 79\x9d\x9d"
	brk
br2	jsr $ab1e
	ldx #0
br3	jsr 65487
	cmp #13
	beq br4
	sta 820,x
	inx
	bne br3
br4	lda #0
	sta 820,x
	ldx #0
	stx 181
br5	lda 820,x
	beq br6
	pha
	lda 181
	asl
	asl
	adc 181
	asl
	sta 181
	pla
	and #15
	clc
	adc 181
	sta 181
	inx
	bne br5
br6	lda 181
	beq breite
	rts
out	ldx #4
	jsr $ffc9
	ldy #0
oc1	lda b,y
	beq oc2
	jsr $ffd2
	iny
	bne oc1
oc2	jsr $aad7
	jsr $ffcc
	jsr 65508
	cmp #"\x03"
	bne cont
	sta 182
cont	ldx #1
	jmp $ffc6