;:sys3671:
	*= $c000
	;.opt oo
tmp	=2
	lda #<hi
	ldy #>hi
	jsr $ab1e
	jmp anfang
hi	.byt 13
	.byte "\x93\x12nss vorspanngenerator basic version 1.0"
	.byte " \xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3"
	.byte " (c)opyright nh 201187 - ein nss programm"
	.byt 13,0
setme	lda #0
	sta 198
c1	lda #<text
c2	ldy #>text
	jsr $ab1e
c3	sei
c4	lda 53266
	cmp #150
	bne c4
	ldx #10
c5	dex
	bne c5
	lda #1
	sta 53280
	sta 53281
c6	lda 53266
	bne c6
	lda 53265
	bmi c6
	lda #14
	sta 53280
	sta 53281
	cli
	lda 198
	beq c3
	jsr 65409
c7	lda #0
c8	ldy #0
	sta 45
	sty 46
	sta 174
	sty 175
c9	jmp 0
text	.byt 13
	.byte "\x93\x11\x11\x11\x11\x11\x11\x11\x11\x11\x11\x11\x05 ZZZ hi ! this is \x12"
	.byte " n s s \x92 again ! ZZZ\x08"
	.byt 13
	.byte "\x11\x9adie nummer eins, wenn's um"
	.byte " software in               bayern geht !\x8e"
	brk
nein	.byte "sorry, aber das programm darf nur aus"
	.byte "   einem sys-befehl beginnen !\x11"
	brk
anfang	lda 45
	sta tmp
	lda 46
	sta tmp+1
ntxt	=text-setme
	lda tmp
	clc
	adc #ntxt
	sta c1+1
	lda tmp+1
	adc #0
	sta c2+1
	lda 45
	sta tmp
	sta c7+1
	lda 46
	sta tmp+1
	sta c8+1
	lda 2053
	cmp #158
	beq jasys
	lda #<nein
	ldy #>nein
	jmp $ab1e
jasys	lda 122
	pha
	lda 123
	pha
	lda #<2054
	ldy #>2054
	sta 122
	sty 123
	jsr 121
	jsr $bcf3
	jsr $b7f7
	sta c9+2
	pla
	sta 123
	pla
	sta 122
	sty c9+1
	ldy #nein-setme-1
copy	lda setme,y
	sta (tmp),y
	dey
	cpy #-1
	bne copy
	lda 45
	clc
	adc #nein-setme
	sta 45
	bcc klein
	inc 46
klein	ldx tmp
	lda tmp+1
	sta $62
	stx $63
	ldx #$90
	sec
	jsr $bc49
	jsr $bddf
	ldx #0
copy2	lda $100,x
	beq fed
	sta 2054,x
	inx
	bne copy2
fed	lda 2054,x
	cmp #"0"
	bcc ok
	cmp #"9"+1
	bcs ok
	lda #58
	sta 2054,x
ok	rts